1 'INTRO LE PERMITE AL USUARIO INDICAR QUE TIPO DE DISPLAY ESTA USANDO Y A SU VEZ CENTRAR LA IMAGEN.-
2 'ESTO ES NECESARIO, PARA PASARLE PARAMETROS AL PROGRAMA "MENU".-
3 '"THORIZ" CONTIENE EL AJUSTE HORIZONTAL PARA MODO GRAFICO Y MODO TEXTO.
4 '"GVERT" CONTIENE EL AJUSTE VERTICAL PARA MODO GRAFICO.
5 '"VERT" CONTIENE EL AJUSTE VERTICAL PARA MODO DE TEXTO.
6 '"DISP" ES "1" SI SELECCIONO COLOR Y "2" PARA BLANCO Y NEGRO.
7 '"MON" 0= b/w,1=rgb,2=tv
10 KEY OFF:FOR I=1 TO 10:KEY I,"":NEXT
20 CLS:GOSUB 60000:GOSUB 61000
25 LOCATE ,,0:GOSUB 1022
30 WIDTH 40:SCREEN 0,1:COLOR 7,0,0:CLS
60 LOCATE 11,3:PRINT "Esta usando pantalla de Color?  (S/N) ";
70 A$=INKEY$: IF A$<>"" THEN 70
80 A$=INKEY$: IF A$="" THEN 80
90 IF A$="S" OR A$="s" THEN DISP=1:GOTO 200
100 IF A$="N" OR A$="n" THEN DISP=2:GOTO 200
110 SOUND 400,4:GOTO 80
200 IF DISP=2 THEN SCREEN ,0:SCREEN ,,2  ELSE SCREEN ,,2
204 COLOR 7,0,3
205 IF DISP=2 THEN SCREEN ,0,,1 ELSE SCREEN ,,,1
210 FOR I=2 TO 10
220 LOCATE I,1,0:COLOR 4:PRINT "   "STRING$(9,219);:COLOR 1:PRINT "    "STRING$(8,219);:COLOR 2:PRINT "    "STRING$(9,219)
230 NEXT
240 COLOR 7,4:LOCATE 6,6:PRINT "ROJO"
250 COLOR 7,1:LOCATE 6,19:PRINT "AZUL"
260 COLOR 7,2:LOCATE 6,31:PRINT "VERDE"
270 COLOR 7,0:LOCATE 12,4:PRINT "1. Use los controles en su TV o"
280 LOCATE 13,7:PRINT "monitor para ajustar la imagen"
290 LOCATE 15,4:PRINT "2. Use las sig. teclas para centrar"
300 LOCATE 16,7:PRINT "la imagen en su pantalla:"
310 COLOR 15:LOCATE 19,7:PRINT "I";:COLOR 7:PRINT "=Izq.,";:COLOR 15:PRINT " D";:COLOR 7:PRINT "=der., ";:COLOR 15:PRINT "S";:COLOR 7:PRINT "=sube ";:COLOR 15:PRINT "B";:COLOR 7:PRINT "=baja"
320 LOCATE 24,3:PRINT "Presione ";:COLOR 15:PRINT CHR$(17)CHR$(196)CHR$(217);:COLOR 7:PRINT " para continuar.";
323 SCREEN ,,0,2
325 THORIZ=45:VERT=28
330 A$=INKEY$: IF A$<>"" THEN 330
340 A$=INKEY$: IF A$="" THEN 340
350 IF A$=CHR$(13) THEN 580
360 IF A$="I" OR A$="i" THEN 520
370 IF A$="D" OR A$="d" THEN 500
380 IF A$="S" OR A$="s" THEN 540
390 IF A$="B" OR A$="b" THEN 560
400 SOUND 400,4:GOTO 330
499 '*** derecha ******
500 IF THORIZ>41 THEN THORIZ=THORIZ-1 ELSE 400
510 GOSUB 600:GOTO 330
519 '*** Izquierda *****
520 IF THORIZ<46 THEN THORIZ=THORIZ+1 ELSE 400
530 GOSUB 600:GOTO 330
539 '*** Arriba ********
540 IF VERT<31 THEN VERT=VERT+1 ELSE 400
550 GOSUB 610:GOTO 330
559 '*** Abajo ******
560 IF VERT>25 THEN VERT=VERT-1 ELSE 400
570 GOSUB 610:GOTO 330
580 GVERT=((VERT-28)*4)+112
590 IF DISP=2 THEN 5000 ELSE 1000
600 OUT 980,2:OUT 981,THORIZ:RETURN
610 OUT 980,7:OUT 981,VERT:RETURN
1000 SCREEN 1,0:COLOR 1,0:CLS:OUT &H3D9,17
1003 OUT 980,7:OUT 981,GVERT:OUT 980,2:OUT 981,THORIZ
1005 DEF SEG:POKE &H4E,3
1010 LOCATE 4,6:PRINT "Tipee 1 si este texto es mas "
1015 LOCATE 7,6:PRINT "legible que el texto de abajo":GOTO 3080
1020 DEF SEG:POKE &H4E,1:LOCATE 15,6:PRINT "Tipee 2 si este texto es mas"
1021 LOCATE 18,6,0:PRINT "legible que el de arriba.    ":RETURN
1022 DEFINT B:DIM BLOCK(1063):GOTO 3000
3000 BLOCK(0)=470:BLOCK(1)=36
3020 FOR J=2 TO 1063:BLOCK(J)=-17477:NEXT
3025 FOR J=31 TO 1063  STEP 59:BLOCK(J)=-17480:NEXT
3027 FOR J=60 TO 1063 STEP 59:BLOCK(J)=-18245:NEXT
3028 RETURN
3080 GOSUB 1020
3090 PUT(34,110),BLOCK,XOR
3100 A$=INKEY$: IF A$<>"" THEN 3100
3110 A$=INKEY$: IF A$="" THEN 3110
3120 IF A$="1" THEN MON=1:GOTO 5000
3130 IF A$="2" THEN MON=2:GOTO 5000
3140 SOUND 400,4:GOTO 3110
5000 '**** ME PREPARO PARA LLAMAR AL MENU **********
5010 DEF SEG=&H4F
5020 POKE 0,THORIZ:POKE 1,GVERT:POKE 2,VERT:POKE 3,MON:POKE 4,DISP:POKE 5,0'SAVE KEY VALUES IN RESERVED MEMORY AREA (TechRef 3-22)
5030 CHAIN "MENU"
60000 REM Me fijo si tiene adaptador de color
60010 DEF SEG=&HB800: POKE 0,250
60020 IF PEEK(0)=250 THEN DEF SEG:RETURN
60025 CLS
60030 PRINT "     Perdon...Este programa requiere el Adaptador de Color"
60040 FOR I= 1 TO 5000 :NEXT :SOUND 400,4:GOTO 60030
61000 REM Monitor de color
61010 DEF SEG=0: POKE &H410,(PEEK (&H410) AND &HCF) OR &H10:DEF SEG
61020 SCREEN 1,0,0,0:SCREEN 0,1:COLOR 1,0:WIDTH 40:COLOR 7,0,0
61030 LOCATE ,,1,6,7:RETURN
61100 REM Pantalla monocromatica
61110 DEF SEG=0:POKE &H410,(PEEK(&H410) OR &H30):DEF SEG
61120 SCREEN 0:WIDTH 80:LOCATE ,,1,12,13:RETURN
